root/bin/pl-init

#!/usr/bin/perl -w

=head1 NAME

pl-init - Initialise a Lancelot mailing list

=head1 SYNOPSIS

 pl-init [-v?] [--clone=otherlist] [--config=FILE] ...
        [--[no]mailfilter] [--our-isp] [--verbose]
          list@domain owner-address key=value ...

=head1 OVERVIEW

The B<pl-init> command creates a new Lancelot mailing list with
a sensible (if basic) configuration.

=head1 DESCRIPTION

The B<pl-init> command creates a new Lancelot mailing list with no
subscribers. It installs a basic configuration (which should be
sensible) and allows the list owner to change individual configuration
settings and/or clone the configuration of another list.

The initial configuration is derived from (1) hard-coded defaults, (2)
the content of a system-wide defaults file (if available), (3) the
content of the user-specific defaults file F<$HOME/.pl/defaults.conf>
(if available), (4) any files whose names are passed on the command line
by means of the B<--config> option, and (5) any configuration parameter
assignments given on the command line, in that order. Later settings
override earlier ones.  Between (3) and (4), the B<list.address> parameter
is set to I<list@domain>, the B<list.owneraddress> parameter is set to
I<owner-address>, the B<list.ownername> parameter is set to the list
owner's name if one is passed as part of I<owner-address>, and the
B<list.name> parameter is set to the local part of I<list@domain>,
capitalised.

Any command-line parameters passed after I<owner-address> will be
considered configuration parameter assignments in the sense of (5) above.
Note that these are pre-parsed by the shell, and USE QUOTES IF YOUR
CONFIGURATION PARAMETER ASSIGNMENTS CONTAIN WHITESPACE.

If a list configuration is "cloned" from that of another list, that
list's configuration is copied to the new list after the defaults
files have been processed but before the configuration files and
parameter assignments given on the command line take effect.
This makes it possible to copy a list's configuration "except for"
some specific settings. The list and owner addresses are set immediately
before the command-line parameter assignments are processed, so they will
be correct for a "cloned" list; you overwrite them from the command line
at your own peril.

The I<owner-address> will also be subscribed to the list as an
administrator. If you'd rather not have this, add the configuration
parameter

  list.subscribeowner = 0

to one of the default files or invoke B<pl-init> like

  pl-init list@domain owner@domain list.subscribeowner=0


=head1 OPTIONS

=over 4

=item B<--clone>=I<otherlist@otherlistdomain>

Copies I<otherlist@otherlistdomain>'s configuration as far as
possible. I<otherlist@otherlistdomain> must belong to the same user
as the new list.

=item B<--config>=I<file>

Reads configuration parameter assignments from I<file>. Empty lines
and comment lines (starting with "#") in I<file> will be ignored.

If B<--config> is used together with B<--clone>, the changes take
place after the configuration has been cloned. There may be multiple
B<--config> options on the same command line. Configuration parameters
may be changed later using the B<pl-conf> command.

=item B<--mailfilter>

For Our-ISP style lists, generates a F<.mailfilter> file
in the list directory which redirects the various list addresses to the
pl-incoming(1) program.

=item B<--nomailfilter>

Causes the program to not generate a F<.mailfilter> file for an
Our-ISP-style Lancelot list.

=item B<--our-isp>

Creates the mailing list according to the conventions of Our-ISP. In
particular, this means that the list database will be created in
F<$HOME/domains/>I<domain>F</>I<list>F</list.db> rather than
F<$HOME/.pl/>I<list>F<@>I<domain>F</list.db>. Implies B<--mailfilter>.

=back

=head1 SEE ALSO

pl-conf(1), pl-init(1), pl-incoming(1), pl-list(1), pl-subchange(1), pl-subscribe(1)

=head1 AUTHOR

Anselm Lingnau <anselm@anselms.net>

=head1 COPYRIGHT AND LICENSE

Copyright 2004-11 by Anselm Lingnau. This program is free software; you
may redistribute it and/or modify it under the terms of the GNU
General Public License as published by the Free Software Foundation;
either version 2 of the License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but
WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program; if not, refer to
<URL:http://www.gnu.org/copyleft/gpl.html>. You may also obtain it by
writing to the Free Software Foundation, Inc., 59 Temple Place - Suite
330, Boston, MA 02111-1307, USA.

=cut

use strict;

# Make Binary find it's libraries for non standard installations ...
use Config;
use File::Basename;
use vars qw($g_base_dir);
BEGIN {
    use FindBin qw($Bin);
    $g_base_dir = dirname ($Bin);
}
use lib "$g_base_dir/lib";
use lib "$g_base_dir/lib/perl5/$Config{version}";
use lib "$g_base_dir/lib/perl5/site_perl/$Config{version}";

use Lancelot::GetOpt qw/GetOptions/;

use Lancelot::DB;
use Lancelot::Log qw/log/;

my %opts;

GetOptions(\%opts, -defaults,
           -argvmin => 2, "need list and owner address",
           "our-isp?", "clone=", "config@", "mailfilter!");

my $listaddr = shift;
my $owneraddr = (Email::Address->parse(shift))[0];
my $ownername = $owneraddr->phrase || $owneraddr->comment;

my %options = ( create => 1, ourisp => $opts{"our-isp"} );

my $db = new Lancelot::DB $listaddr, \%options
    or die "$0: error creating list $listaddr\n";

clone_list($db, $opts{clone}) if $opts{clone};

$db->set_config("list.address", $listaddr);
$db->set_config("list.owneraddress", $owneraddr->address);
$db->set_config("list.ownername", $ownername) if $ownername;
my $listname = $listaddr;
$listname =~ s/\@.*$//;
$db->set_config("list.name", ucfirst($listname));

$db->set_configs_from_file($_, 0) foreach @{$opts{config}};
$db->set_configs(@ARGV) if @ARGV;

if ($opts{"our-isp"} && !($opts{mailfilter} == 0)) {
    my ($mfname) = File::Spec->join($db->get_listdir, ".mailfilter");
    log "info", "creating mailfilter file $mfname";
    my ($mfh) = IO::File->new("> $mfname");

    if ($mfh) {
        print $mfh qq{to "|$Bin/pl-incoming $listaddr"\n};
        $mfh->close;
        chmod 0600, $mfname;
    } else {
        die "$0: couldn't create $mfname: $!\n";
    }
} else {
    my $xlistaddr = $listaddr;
    my $delim = $db->get_config("mail.delimiter");
    $xlistaddr =~ s/\@/${delim}ANYTHING\@/;
    my $user = getpwuid($<);

    print "Make sure that within your MTA setup, messages to\n\n";
    print "    $listaddr   as well as\n";
    print "    $xlistaddr\n\n";
    print "are piped into\n\n";
    print "    $Bin/pl-incoming --user $user $listaddr\n\n";
    print "Consult Project Lancelot's Deployment-HOWTO for details.\n";
}

my $subscribe_owner = $db->get_config("list.subscribeowner");
if ($subscribe_owner) {
    log "info", "subscribing owner address as list administrator";
    unless ($db->add_address($owneraddr, { admin => 1 })) {
        log "err", "error subscribing $owneraddr\n";
    }
}

sub clone_list {
    my ($db, $clonelist) = @_;

    log "info", "cloning list $clonelist";
    my ($db1) = new Lancelot::DB $clonelist
        or die "$0: list $clonelist does not exist\n";
    foreach my $c ($db1->config_names) {
        $db->set_config($c, $db1->get_config($c));
    }
}