root/bin/pl-unsubscribe

#!/usr/bin/perl

=head1 NAME

pl-unsubscribe - Remove addresses from a Lancelot list's subscriber database

=head1 SYNOPSIS

  pl-unsubscribe [-gv?] [--[no]goodbye] [--verbose] list@domain
      [address ...]

=head1 OVERVIEW

The B<pl-unsubscribe> command allows a list owner to remove addresses
from a list's subscriber database manually.  Addresses may be listed
on the command line or fed to the command on its standard input.

=head1 DESCRIPTION

The B<pl-unsubscribe> command takes addresses from the command line or,
alternatively, standard input (if none are specified on the command
line) and removes them from the given list's subscriber database.

=head1 OPTIONS

=over 4

=item B<--goodbye>, B<-g>

A copy of the list's "goodbye message" is sent to the addresses after they
have been unsubscribed. This option is ignored if the B<--confirm> option
was also specified.

=item B<--help>, B<-?>

Causes the program to output a brief usage explanation and exit.

=item B<--nogoodbye>

No "goodbye message" will be sent to the addresses.

=item B<--verbose>, B<-v>

Causes the program to output messages about its progress to the
standard error channel.

=back

=head1 SEE ALSO

pl-conf(1), pl-init(1),  pl-list(1), pl-subchange(1), pl-subscribe(1)

=head1 AUTHOR

Anselm Lingnau <anselm@anselms.net>

=head1 COPYRIGHT AND LICENSE

Copyright 2004 by Anselm Lingnau. This program is free software; you
may redistribute it and/or modify it under the terms of the GNU
General Public License as published by the Free Software Foundation;
either version 2 of the License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but
WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program; if not, refer to
<URL:http://www.gnu.org/copyleft/gpl.html>. You may also obtain it by
writing to the Free Software Foundation, Inc., 59 Temple Place - Suite
330, Boston, MA 02111-1307, USA.

=cut

use strict;

# Make Binary find it's libraries for non standard installations ...
use Config;
use File::Basename;
use vars qw($g_base_dir);
BEGIN {
    use FindBin qw($Bin);
    $g_base_dir = dirname ($Bin);
}
use lib "$g_base_dir/lib";
use lib "$g_base_dir/lib/perl5/$Config{version}";
use lib "$g_base_dir/lib/perl5/site_perl/$Config{version}";

use Lancelot::GetOpt qw/GetOptions/;

use Lancelot::DB;
use Lancelot::Send;
use Lancelot::Module::unsubscribe_user; # for goodbye-message
use Lancelot::Log qw/log/;

my %opts;

GetOptions(\%opts, -defaults => 1, -argvmin => 1, "no list address specified",
           "goodbye|g!");

my $listaddr = shift;

my $db = new Lancelot::DB $listaddr
    or die "$0: error accessing list $listaddr\n";

my $conf_goodbye = $db->get_config("unsubscribe.goodbye");
$opts{goodbye} = $opts{goodbye} != -1 ? $opts{goodbye}
                          : (defined $conf_goodbye ? $conf_goodbye : 1);

my (@addrs) = @ARGV;
if (@ARGV == 0) {
    @addrs = grep { chomp; !/^\s*$/ && !/^\#/ } <STDIN>;
}

foreach my $a (@addrs) {
    if ($db->set_address_options($a, { status => 'DELETE' })) {
        &send_goodbye($a) if $opts{goodbye};
        print STDERR "$a unsubscribed\n" if $::verbose;
    } else {
        warn "$0: error unsubscribing $a\n";
    }
}

sub send_goodbye {
    my ($address) = @_;
    print STDERR "Sending goodbye message to $address\n" if $::verbose;
    Lancelot::Send::sendtemplate("goodbye-message", $db, undef,
                                 { "subscriber" => $address });
}