root/t/01message.t

#!/usr/bin/perl -w

use Test::More tests => 13;
use Test::Exception;

BEGIN { use_ok(Lancelot::Message); }

my $msg;
dies_ok { $msg = new Lancelot::Message } "new() for empty text";

# $msg = new Lancelot::Message(<<END);
# xyzzy
# foobar
# baz
# quux
# END
# It turns out that Email::Simple doesn't actually mind this.
# ok( defined $msg, "new() for non-RFC2822 text" );

$msg = new Lancelot::Message(<<'END');
From: hugo@example.com
To: susi@example.net
Subject: Test
X-Test: blafasel
X-Multiline: bla
  fasel
Content-Type: text/plain; charset="iso-8859-1"
Content-Transfer-Encoding: quoted-printable

Dies ist ein Test.
END
ok( defined $msg, "new() for RFC2822 message" );
ok( $msg->isa('Lancelot::Message'), "correct class" );
ok( $msg->isa('Email::MIME'), "correct superclass" );

$msg->set_flag('bla', 'fasel');
is( $msg->get_flag('bla'), 'fasel', "set_flag/get_flag test");

is( $msg->header('X-Multiline'), 'bla fasel', "header folding" );

my $correct = 'From: hugo@example.com
To: susi@example.net
Subject: Test
X-Test: blafasel
X-Multiline: bla
  fasel
Content-Type: text/plain; charset="iso-8859-1"
Content-Transfer-Encoding: quoted-printable
';
is( $msg->headers_raw(), $correct, "raw headers");
$msg->header_set('X-Bla', 'Fasel');
is( $msg->header('X-Bla'), 'Fasel', "header_set check");
$msg->header_set('X-Bla', 'Fasel', 'Blubb');
my @h = $msg->header('X-Bla');
is_deeply(\@h , ['Fasel','Blubb'], "header_set check (array)");

$msg->header_remove('X-Test');
ok( !defined $msg->header('X-Test'), "header_remove check");

$msg->header_set('X-EncTest', 'Ein ÄÖÜäöüß-Test');
is($msg->header('X-EncTest'), 'Ein ÄÖÜäöüß-Test', "header_encode test");
$msg->header_encode('X-EncTest', 'quoted-printable');

# We can't test it simply like this because Email::MIME helpfully
# decodes the header for us.
#
# is($msg->header('X-EncTest'), 'Ein =?iso-8859-1?Q?=C4=D6=DC=E4=F6=FC=DF?=-Test',
#                 "header_encode test");

TODO: {
    local $TODO = "header_encode isn't really testable";

    my ($x) = $msg->__head->as_string =~ /^X-EncTest:\s+(.*)$/m;
    is( $x, 'Ein =?iso-8859-1?Q?=C4=D6=DC=E4=F6=FC=DF-Test?=',
        "header_encode check" );
    diag($msg->__head->as_string);
}