root/t/01template.t

#!/usr/bin/perl -w

use Test::More tests => 21;
use Test::Exception;
use Sub::Override;
use File::Spec;
use File::Path;

use Lancelot::DB;
BEGIN { use_ok(Lancelot::Template); }

# This must not conflict with a real list name.

my ($listname_local, $listname_domain) = ('pl-testlist', 'example.com');
my $listname = "$listname_local\@$listname_domain";
rmtree("$ENV{HOME}/.pl/$listname");
my $db = new Lancelot::DB $listname, { create => 1 };
$db->delete_configs("lancelot.templatedirs");

# Tests for replacement()

# simple replacement from key=>value hash
is (Lancelot::Template::replacement($db, { "foo" => "BAR" }, "foo"), "BAR",
    "replace test (simple)");
# replacement from default value
is (Lancelot::Template::replacement($db, {}, "foo"), undef,
    "replace test (empty default)");
is (Lancelot::Template::replacement($db, {}, "foo|QUUX"), "QUUX",
    "replace test (specified default)");
is (Lancelot::Template::replacement($db, { "foo" => "BAR" }, "foo|QUUX"),
    "BAR", "replace test (simple & specified default)");
# replacement from configuration
$db->set_config("foo", "BAZ");
is (Lancelot::Template::replacement($db, {}, "foo"), "BAZ",
    "replace test (from configuration)");
is (Lancelot::Template::replacement($db, { "foo" => "BAR" }, "foo"), "BAR",
    "replace test (simple & from configuration)");
# time format
is (Lancelot::Template::replacement($db, { "t" => 1234567890 },
                                    "t%dd.mm.yyyy, hh.mm.ss"),
    "14.02.2009, 00.31.30", "replace test (time format)");

# Tests for register()

ok( Lancelot::Template->register("test", "en", "foobar"),
    "register (non-existing template)" );
ok( Lancelot::Template->register("test", "en", "foobar"),
    "register (existing template)" );

# Tests for find() and process()

my $tdir = File::Spec->join($db->get_listdir, "templates", "en");
mkpath $tdir;
open OUT, "> ".File::Spec->join($tdir, "pl-test1");
print OUT "Test\n";
close OUT;

is (Lancelot::Template::find($db, "pl-test1", "en"), "Test\n",
    "find (listdir)");
is (Lancelot::Template->process("pl-test1", "en", $db, {}), "Test\n",
    "process (simple)");
rmtree(File::Spec->join($db->get_listdir, "templates"));

$tdir = File::Spec->join($ENV{HOME}, '.pl', 'templates', 'en');
mkpath $tdir unless -d $tdir;
open OUT, "> ".File::Spec->join($tdir, "pl-test2");
print OUT "Test\n";
close OUT;

is (Lancelot::Template::find($db, "pl-test2", "en"), "Test\n",
    "find (home directory)");
my $saved_home = $ENV{'HOME'};
delete $ENV{'HOME'};
is (Lancelot::Template::find($db, "pl-test2", "en"), "Test\n",
    "find (home dir, with default from /etc/passwd)");
my $override = Sub::Override->new(
    'Lancelot::Template::get_homedir' => sub { return undef; }
    );
is (Lancelot::Template::find($db, "pl-test2", "en"), undef,
    "find (home dir, with overridden getpwuid)");
$override->restore();
$ENV{'HOME'} = $saved_home;

unlink File::Spec->join($ENV{HOME}, '.pl', 'templates', 'en', 'pl-test2');

$tdir = File::Spec->join("/tmp", "pl-test3", "en");
mkpath $tdir unless -d $tdir;
open OUT, "> ".File::Spec->join($tdir, "pl-test3");
print OUT "Test\n";
close OUT;

ok (!defined Lancelot::Template::find($db, "pl-test3", "en"),
    "find (templatedirs not set)");
$db->set_config("lancelot.templatedirs", "/tmp/pl-test3");
is (Lancelot::Template::find($db, "pl-test3", "en"), "Test\n",
    "find (templatedirs set)");
rmtree(File::Spec->join("/tmp", "pl-test3"));

$db->delete_configs("lancelot.templatedirs");
ok (!defined Lancelot::Template->process("pl-test4", "en", $db, {}),
    "process (undefined template)");
Lancelot::Template->register("pl-test4", "en", "Hello world\n");
is (Lancelot::Template->process("pl-test4", "en", $db, {}), "Hello world\n",
    "process (fallback to registered template)");
is (Lancelot::Template->process("pl-test4", "de", $db, {}), "Hello world\n",
    "process (fallback to registered template - in English)");

Lancelot::Template->register("pl-test5", "en", "a<<b>>c\n");
is (Lancelot::Template->process("pl-test5", "en", $db, { b => 'B' }), "aBc\n",
    "process (with replacement)");