root/t/80remote-adm.t

#!/usr/bin/perl -w
# Test remote administration capability

use strict;

BEGIN { chdir 't' if -d 't' }
use lib '../lib';

use Test::More tests => 2;
use Test::File::Contents;

use Lancelot::SMTPTest qw/run_program/;

use File::Path;
use Lancelot::DB;

my $smtpport = 4712;            # for now
my $dir = "../smtp-test";

my $listname = 'pl-testlist@example.com';

rmtree("$ENV{HOME}/.pl/$listname", 0);

my $db = new Lancelot::DB $listname, { create => 1 };
$db->set_config('list.name', 'Pl-testlist');
$db->set_config('smtp.server', 'localhost');
$db->set_config('smtp.port', $smtpport);
$db->set_config('mail.workflow.admin', 'admin');
$db->set_config('mail.delimiter', '+');
$db->add_address('hugo@example.com');

my @cmd = ('../blib/script/pl-incoming', '--verbose=STDERR:all=debug', $listname);

# First try sending an administrative request to a non-administrator

my $message = <<'END';
Delivered-To: pl-testlist+admin@example.com
Return-Path: hugo@example.com
From: hugo@example.com
To: pl-testlist+admin@example.com
Subject: remote admin test
Message-ID: <ra-1@example.com>

list
END

run_program("lrr-na", \@cmd, $message, $dir);

file_contents_is("$dir/msg.lrr-na.0", <<'END', "list request reply (not admin)");
SMTP-From: pl-testlist+owner@example.com
SMTP-To: hugo@example.com
From: Pl-testlist Management <pl-testlist+owner@example.com>
To: hugo@example.com
Subject: Unauthorised administrative request (remote admin test)
In-Reply-To: <ra-1@example.com>

You tried to send an administrative request to the list but we do not
have you down as a list administrator. Your message has been ignored.

Do not hesitate to contact us if you have any questions.

The Pl-testlist Management Team

END

# Now try it as an administrator

$db->set_address_options('hugo@example.com', { admin => 1 });

run_program("lrr", \@cmd, $message, $dir);

file_contents_eq_or_diff("$dir/msg.lrr.0", <<'END', "list request reply", { style => 'Unified' });
SMTP-From: pl-testlist+owner@example.com
SMTP-To: hugo@example.com
From: Pl-testlist Management <pl-testlist+owner@example.com>
To: hugo@example.com
Subject: Results of your administrative request (remote admin test)
In-Reply-To: <ra-1@example.com>

Thank you for your administrative request. Here are the results:

.. list
SA---- hugo@example.com

(Lines beginning with ".." echo your commands. Lines beginning with
"I:" contain informational messages, and lines beginning with "E:"
contain error messages. If an error message appears, the operation
in question will not have been performed.)

Do not hesitate to contact us if you have any questions.

The Pl-testlist Management Team

END